Files
KART-SERVER-JAVA/build.gradle

106 lines
3.3 KiB
Groovy

plugins {
id 'java'
id 'org.springframework.boot' version '3.5.7'
id 'io.spring.dependency-management' version '1.1.7'
}
group = 'com.kri.kart.server'
version = '0.0.1-SNAPSHOT'
description = 'KART 백엔드 API'
java {
toolchain {
languageVersion = JavaLanguageVersion.of(17)
}
}
configurations {
compileOnly {
extendsFrom annotationProcessor
}
}
def giteaUser = findProperty('giteaUser')
?: System.getenv('GITEA_MAVEN_USER')
?: ''
def giteaToken = findProperty('giteaToken')
?: System.getenv('GITEA_MAVEN_TOKEN')
?: ''
def kiwiVersion = 'v0.24.0'
def kiwiPlatform = findProperty('kiwiPlatform') ?: (System.getProperty('os.name').toLowerCase().contains('windows') ? 'win-x64' : (System.getProperty('os.arch') == 'aarch64' ? 'lnx-aarch64' : 'lnx-x86-64'))
repositories {
mavenCentral()
ivy {
name = 'kiwiReleases'
url = uri('https://github.com/bab2min/Kiwi/releases/download')
patternLayout { artifact '[revision]/[artifact]-[revision]-[classifier].[ext]' }
metadataSources { artifact() }
content { includeModule('kr.pe.bab2min', 'kiwi-java') }
}
maven {
name = 'gitea'
url = uri('https://gitea.kric.com/api/packages/KRi/maven')
credentials {
username = giteaUser
password = giteaToken
}
}
}
configurations.configureEach {
resolutionStrategy.cacheDynamicVersionsFor 0, 'seconds'
}
dependencies {
implementation 'com.kri.common:starter:beta.1.6.9'
implementation 'org.apache.poi:poi-ooxml:5.5.1'
implementation "kr.pe.bab2min:kiwi-java:${kiwiVersion}:${kiwiPlatform}@jar"
implementation 'org.springframework.boot:spring-boot-starter-web'
implementation 'org.springframework.boot:spring-boot-starter-security'
implementation 'org.springframework.boot:spring-boot-starter-validation'
implementation 'org.springframework.boot:spring-boot-starter-jdbc'
// Common API Key persistence only; business databases use MyBatis.
implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.11'
runtimeOnly 'com.microsoft.sqlserver:mssql-jdbc:13.2.1.jre11'
runtimeOnly 'com.mysql:mysql-connector-j'
implementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter:3.0.5'
compileOnly 'org.projectlombok:lombok'
annotationProcessor 'org.projectlombok:lombok'
developmentOnly 'org.springframework.boot:spring-boot-devtools'
testImplementation 'org.springframework.boot:spring-boot-starter-test'
testImplementation 'org.springframework.security:spring-security-test'
testImplementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter-test:3.0.5'
testImplementation 'com.h2database:h2'
testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}
tasks.withType(JavaCompile).configureEach {
options.encoding = 'UTF-8'
}
tasks.withType(Test).configureEach {
jvmArgs '-Dfile.encoding=UTF-8'
}
tasks.withType(JavaExec).configureEach {
jvmArgs '-Dfile.encoding=UTF-8'
}
tasks.named('test') {
if (project.hasProperty('kiwiModelDirectory')) {
systemProperty 'kart.kiwi.model-directory', project.property('kiwiModelDirectory')
}
useJUnitPlatform()
}