Files
common-library/build.gradle

80 lines
2.4 KiB
Groovy

plugins {
id 'java-library'
id 'maven-publish'
}
//버전 변경은 여기서
def commonVer = "1.0.2"
group = 'com.kri.common'
version = commonVer
java {
toolchain { languageVersion = JavaLanguageVersion.of(17) }
}
repositories {
mavenCentral()
}
dependencies {
// 공통 BOM 객체 하나 잡아두고
def springBootBom = platform('org.springframework.boot:spring-boot-dependencies:3.5.7')
// 여기까지가 BOM 적용 구간
api springBootBom
compileOnly springBootBom
annotationProcessor springBootBom
// ==== 여기부터는 버전 안 써도 됨 (BOM이 버전 정해줌) ====
// JWT
api 'io.jsonwebtoken:jjwt-api:0.11.5'
runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.11.5'
// Security Core
api 'org.springframework.security:spring-security-core'
// Swagger / OpenAPI 어노테이션 (@Schema 등) - 컴파일용
compileOnly 'io.swagger.core.v3:swagger-annotations:2.2.25'
// Lombok
compileOnly 'org.projectlombok:lombok'
annotationProcessor 'org.projectlombok:lombok'
// ConfigurationProperties 메타데이터
annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'
compileOnly 'org.springframework.boot:spring-boot-autoconfigure'
// 자동구성/웹/검증/AOP/Redis는 컴파일만 (전이 방지)
compileOnly 'org.springframework.boot:spring-boot-autoconfigure'
compileOnly 'org.springframework.boot:spring-boot-starter-web'
compileOnly 'org.springframework.boot:spring-boot-starter-validation'
compileOnly 'org.springframework.boot:spring-boot-starter-aop'
compileOnly 'org.springframework.boot:spring-boot-starter-data-redis'
}
def giteaUser = findProperty("giteaUser") ?: ""
def giteaToken = findProperty("giteaToken") ?: ""
publishing {
publications {
release(MavenPublication) {
from components.java
groupId = 'com.kri.common'
artifactId = 'starter' // 소비 프로젝트에서 쓰는 artifactId
version = commonVer
}
}
repositories {
maven {
name = "gitea"
url = uri("http://10.10.10.11:3000/api/packages/KRi/maven") // owner=KRi
allowInsecureProtocol = true
credentials {
username = giteaUser // 또는 본인 계정
password = giteaToken
}
}
}
}